XQuery 4.0: An XML Query Language

4.18 Switch Expressions

The switch expression chooses one of several expressions to evaluate based on the input value.

In a switch expression, the switch keyword is followed by an expression enclosed in parentheses, called the switch comparand. This is the expression whose value is being compared. This expression is optional, and defaults to true(). The remainder of the switch expression consists of one or more case clauses, with one or more case operand expressions each, and a default clause.

The first step in evaluating a switch expression is to apply atomization to the value of the switch comparand. Call the result the switch value. If the switch value is a sequence of length greater than one, a type error is raised [err:XPTY0004]. In the absence of a switch comparand, the switch value is the xs:boolean value true.

The switch value is compared to each SwitchCaseOperand in turn until a match is found or the list is exhausted. The matching is performed as follows:

1. The SwitchCaseOperand is evaluated.

2. The resulting value is atomized: call this the case value.

3. If the case value is an empty sequence, then a match occurs if and only if the switch value is an empty sequence.

4. Otherwise, the singleton switch value is compared individually with each item in the case value in turn, and a match occurs if and only if these two atomic items compare equal under the rules of the fn:deep-equal function with default options, using the default collation in the static context.

[Definition: The effective case of a switch expression is the first case clause that matches, using the rules given above, or the default clause if no such case clause exists.] The value of the switch expression is the value of the return expression in the effective case.

Switch expressions have rules regarding the propagation of dynamic errors: see 2.4.5 Guarded Expressions. These rules mean that the return clauses of a switch expression must not raise any dynamic errors except in the effective case. Dynamic errors raised in the operand expressions of the switch or the case clauses are propagated; however, an implementation must not raise dynamic errors in the operand expressions of case clauses that occur after the effective case. An implementation is permitted to raise dynamic errors in the operand expressions of case clauses that occur before the effective case, but not required to do so.

The following example shows how a switch expression might be used:

switch ($animal) {
  case "Cow" return "Moo"
  case "Cat" return "Meow"
  case "Duck", "Goose" return "Quack"
  default return "What's that odd noise?"
}

The curly brackets in a switch expression are optional. The above example can equally be written:

switch ($animal) 
  case "Cow" return "Moo"
  case "Cat" return "Meow"
  case "Duck", "Goose" return "Quack"
  default return "What's that odd noise?"

The following example illustrates a switch expression where the comparand is defaulted to true:

switch {
  case ($a le $b) return "lesser"
  case ($a ge $b) return "greater"
  case ($a eq $b) return "equal"
  default return "not comparable"
}

switch () {
  case ($a le $b) return "lesser"
  case ($a ge $b) return "greater"
  case ($a eq $b) return "equal"
  default return "not comparable"
}