This section describes the overall structure of a stylesheet as a collection of XML documents.
Changes in 4.0 (next | previous)
Simplified stylesheets no longer require an xsl:version attribute (which means they might not need a declaration of the XSLT namespace). Unless otherwise specified, a 4.0 simplified stylesheet defaults expand-text to true. [Issue 90 PR 599 12 September 2023]
The outermost element of a simplified stylesheet need no longer be a literal result element, it can now be any instruction (including xsl:result-document). This allows a simplified stylesheet to produce JSON output as well as XML or HTML. [Issue 2322 PR 2323 30 November 2025]
A simplified syntax is allowed for a stylesheet module that defines only a single template rule. A simplified stylesheet module consist of a single instruction or literal result element together with its contents. Such a stylesheet module is equivalent to a standard stylesheet module whose xsl:stylesheet element contains a template rule containing the instruction or literal result element; the template rule has a match pattern of match=".", which matches any item.
The following example shows a stylesheet that simply evaluates one XPath expression:
The output of the stylesheet will be an XML document such as <out>17</out> showing the number of elements found in the supplied source document.
This simplified stylesheet is defined to be equivalent to the following expanded stylesheet:
<xsl:stylesheet xmlns="http://www.w3.org/1999/XSL/Transform"
version="4.0" expand-text="yes">
<xsl:template match=".">
<out>{count(//*)}</out>
</xsl:template>
</xsl:stylesheet>Because the stylesheet contains no elements or attributes in the XSLT namespace, it does not need to contain any namespace declarations.
A simplified stylesheet can contain XSLT instructions, in which case the XSLT namespace needs to be declared. This is illustrated in the next example.
This stylesheet outputs an HTML document containing a table that summarizes the value of transactions according to their rate of tax:
<html xmlns="http://www.w3.org/1999/xhtml"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xsl:version="4.0">
<head>
<title>Expenditure by Tax Rate</title>
</head>
<body>
<table>
<thead>
<tr>
<th>Gross Amount</th>
<th>Tax Rate</th>
</tr>
</thead>
<tbody>
<xsl:for-each-group select="//transaction" group-by="vat-rate">
<tr>
<td>{sum(current-group()/value)}</td>
<td>{current-grouping-key()}</td>
</tr>
</xsl:for-each-group>
</tbody>
</table>
</body>
</html>
This example expects as input a parsed JSON document containing an array of records. It outputs a serialized JSON document containing a selection of fields from these records.
<xsl:result-document method="json" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:array>
<xsl:for-each select="?*">
<xsl:record first="?firstName"
last="?surname"
phone="?mobile"/>
</xsl:for-each>
</xsl:array>
</xsl:result-document>More formally, a simplified stylesheet module is equivalent to the standard stylesheet module that would be generated by applying the following transformation to the simplified stylesheet module, invoking the transformation by calling the named templateexpand, with the outermost element as the context node:
<xsl:stylesheet version="4.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template name="expand">
<xsl:element name="xsl:stylesheet">
<xsl:variable name="version"
select="(if (self::xsl:*) then @version else @xsl:version)
otherwise '4.0'"/>
<xsl:attribute name="version" select="$version"/>
<xsl:attribute name="expand-text"
select="not(number($version) le 3.0)"/>
<xsl:element name="xsl:template">
<xsl:attribute name="match" select="'.'"/>
<xsl:copy-of select="."/>
</xsl:element>
</xsl:element>
</xsl:template>
</xsl:stylesheet>The allowed content of an instruction or literal result element when used as a simplified stylesheet is the same as when it occurs within a sequence constructor. Thus, a simplified stylesheet cannot contain declarations. In particular, simplified stylesheets therefore cannot use template rules, global variables, stylesheet parameters, stylesheet functions, keys, attribute-sets, or output definitions. Furthermore, they cannot contain xsl:include, xsl:import, or xsl:use-package declarations.
The only useful way to initiate the transformation is to supply an item as the initial match selection, to be matched by the implicit match="." template rule using the unnamed mode.
Note:
There are several significant changes to simplified stylesheets in XSLT 4.0.
It is no longer required to include an xsl:version attribute; this in turn means it is often no longer necessary to declare the xsl namespace. The xsl:version attribute defaults to the version of the XSLT processor, that is, "4.0" for an XSLT 4.0 processor.
If the xsl:version attribute is omitted, or is set to "4.0" or a larger value, then the expand-text attribute defaults to true, meaning that text value templates are recognized.
The outermost element of a simplified stylesheet can be any instruction (for example, xsl:array, xsl:map, or xsl:result-document), allowing the stylesheet to deliver arrays, maps, or serialized JSON.
The match pattern of the implicit template rule uses match="." rather than match="/", allowing the to be any item, not only a document node.The match pattern of the implicit template rule uses match="." rather than match="/", allowing the initial match selection to be any item, not only a document node.The match pattern of the implicit template rule uses match="." rather than match="/", allowing the initial match selection to be any item, not only a document node.
There may be edge cases where this causes a backwards incompatibility. For example, if a transformation using a simplified stylesheet is invoked supplying an element node (rather than a document node) as the initial match selection, then under 4.0 this will match the implicitly-defined template rule (match="." matches an element node), whereas in 3.0 it would have been processed using the built-in template rules for the unnamed mode. A similar situation arises if a simplified stylesheet module is imported into a larger stylesheet package, and the implicitly-defined template rule is invoked using xsl:next-match or xsl:apply-imports.
Note:
It is technically valid for the outermost element to be xsl:variable or xsl:param, because these are defined as instructions; however, this achieves no useful purpose because the result of these instructions is an empty sequence.