XQuery 4.0: An XML Query Language

5.20 Named Record Types

Although item type declarations, as described in 5.19 Item Type Declarations, can be used to give names to record types as well as any other item type, named record types as described in this section provide a more concise syntax, plus additional functionality. In particular:

• Named record types can be recursive.

• Named record types implicitly create a constructor function that can be used to create instances of the record type.

• A field in a named record type can be a function that has implicit access to the record on which it is defined, rather like methods in object-oriented languages.

The syntax is as follows:

A named record declaration serves as both a named item type and as a function definition, and it therefore inherits rules from both these roles. In particular:

1. Its name must not be the same as the name of any other named item type, or any generalized atomic type, that is present in the same static context [err:XQST0048].

2. If the declaration is public and is within a library module, then its name must be in the target namespace of the library module [err:XQST0048].

3. As a function, it must not have an arity range that overlaps the arity range of any other function declaration having the same name in the same static context.

4. The order of field declarations is significant, because it determines the order of arguments in a call to the constructor function.

5. The fields must have distinct names. [err:XPST0021]

6. In order to work as both a record type and a function declaration, the names of the fields must be simple NCNames in no namespace; the names must not be written as string literals [err:XPST0003].

   Note:

   This is described here as a semantic constraint, but an implementation might choose to impose it at the level of the grammar.

7. If an initializing expression is present in an ExtendedFieldDeclaration, it must follow the rules for the initializing expression of a parameter in a function declaration, given in 5.18.3 Function Parameters. In particular, if any field has an initializing expression then all following fields must have an initializing expression.

8. Any annotations that are present, such as %public or %private, apply both to the item type declaration and to the function declaration.

declare record geom:rectangle(
  width as xs:double,
  height as xs:double,
  area as fn($rect as map(*)) as xs:double := fn($rect) { 
    $rect -> ?width × ?height
  },
  perimeter as fn($rect as map(*)) as xs:double := fn($rect) {
    $rect -> 2 × (?width + ?height)
  },
  expand as fn($rect as map(*), $factor as xs:double) as geom:rectangle := fn() {
    $rect -> geom:rectangle(?width × $factor, ?height × $factor)
  }   
);

declare record my:rectangle (
   height as xs:double,
   width as xs:double,
   area as fn(my:rectangle) as xs:double 
     := fn{?height × ?width},
   resize as fn(my:rectangle, xs:double) as my:rectangle 
     := fn($rect, $factor) {
           $rect => map:put('height', $rect?height × $factor)
                 => map:put('width', $rect?width × $factor)
        }
);

let $box := geom:rectangle(3, 2)
return $box ?> area()

let $box := my:rectangle(3, 2)
return $box ?> area()

let $box := geom:rectangle(3, 2)
return $box ?> expand(2) ?> perimeter()

let $box := my:rectangle(3, 2)
return $box ?> expand(2) ?> perimeter()